home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
LOGIC Apps
/
Logic-APPLE_II_APPS.iso
/
mac
/
LOGIC Apple II 5.25" Library - ProDOS
/
PRO102.dsk
/
READER
/
DOC.READER.bas
next >
Wrap
BASIC Source File
|
2012-02-16
|
3KB
|
58 lines
100 REM AWP/TEXT FILE VIEWER, VER 1.0, 01/09/90
110 REM TONY PIZZA, 1553 ROYCE CT,CAMARILLO CA 93010
120 REM COMPUSERVE 72257,160; GENIE A.PIZZA
150 D$ = CHR$(4)
152 ONERR GOTO 4010
155 PRINT D$"-DOGPAW"
157 REM DOGPAW VER 3.30 BY KARL BUNKER,321 S. HUNTINGTON AVE,BOSTON MA 02130
160 PRINT D$"PREFIX": INPUT PF$: REM CURRENT DISK ONLY
170 REM CHECK FOR 80 COLUMN
180 HOME :VS = ( INT( PEEK( -15604)/16) = 8) *3
1015 DIM F$(60): DIM TP$(60)
3000 REM GET AWP/TXT FILES
3010 I = 1
3015 GOSUB 4040: ONERR GOTO 4000: REM DISK GONE?
3020 PRINT D$"OPEN ";PF$",TDIR"
3030 PRINT D$"READ "PF$
3040 INPUT DR$
3050 INPUT I$
3060 ONERR GOTO 3110: REM END READ
3065 INPUT I$
3080 TP$(I) = MID$ (I$,18,3)
3097 IF TP$(I) = "AWP" OR TP$(I) = "TXT" THEN F$(I) = MID$ (I$,2,16):I = I +1
3100 GOTO 3065
3110 CALL 62248: POKE 216,0: PRINT D$"CLOSE"
3120 NE = I -1
3130 PRINT CHR$(24): PRINT CHR$(4)"PR#"VS: REM ENSURE MOUSETEXT OFF
3135 IF NE = >60 THEN PRINT "Sorry, can only show the first 60 ";
3140 PRINT "FILES : "PF$: PRINT : REM PUT FILES IN COLUMNS
3150 FOR I = 1 TO 20: PRINT I;: POKE 36,3: PRINT F$(I);: POKE 36,20: PRINT TP$(I): NEXT
3152 IF NE >20 THEN VTAB 3: FOR I = 21 TO 40: POKE 36,25: PRINT I;: POKE 36,28: PRINT F$(I);: POKE 36,45: PRINT TP$(I): NEXT
3154 IF NE >40 THEN VTAB 3: FOR I = 41 TO 60: POKE 36,50: PRINT I;: POKE 36,53: PRINT F$(I);: POKE 36,75: PRINT TP$(I): NEXT
3160 PRINT : INPUT "SELECT FILE TO VIEW BY NUMBER, OR RETURN FOR NO SELECTION > ";SF$
3165 SF = VAL(SF$)
3167 IF F$(SF) = "" THEN GOTO 3200
3170 GOSUB 4200: PRINT D$;"DOGPAW";F$(SF)
3180 GOTO 3130
3200 HOME : VTAB 3
3210 PRINT "SPACE - SELECT ANOTHER FILE"
3230 PRINT "RETURN - QUIT TO BASIC"
3240 PRINT : GET SEL$
3245 IF SEL$ = CHR$(13) THEN GOTO 4100
3250 GOTO 3130
4000 POKE 216,0: VTAB 18: PRINT "DISK ERROR, CHECK DRIVE": PRINT CHR$(7): FOR I = 1 TO 250: NEXT : GOTO 3000
4010 POKE 216,0: VTAB 18: PRINT "THIS PROGRAM ALSO NEEDS DOGPAW ON DISK TO WORK": END
4040 PRINT "AWP/TEXT FILE READER VER. 1.0": PRINT
4042 PRINT " BY TONY PIZZA"
4043 PRINT " 1/9/90": PRINT : PRINT
4045 PRINT "WORKING - DON'T RESET"
4050 PRINT "TAKES TIME WHEN THERE ARE MANY FILES": PRINT : RETURN
4100 PRINT : PRINT CHR$(4)"NODOGPAW"
4110 REM
4120 REM
4150 PRINT "CURRENT PATH LOGGED IS "PF$
4160 END
4200 HOME : PRINT : PRINT "Print Out ? (printer in Slot 1 only)": PRINT "Y for Printout, Any key for screen >";
4210 GET A$: PRINT A$
4220 IF A$ = "Y" OR A$ = "y" THEN PRINT D$"pr#1"
4230 RETURN